REBOL [
	Title: "REBOL Logo Maker"
	Purpose: "Scale and Save REBOL Logo Image"
	Author: ["Carl Sassenrath" "Gabriele Santilli"]
	Version: 1.0.0
	Rights: "REBOL logo is a registered trademark of REBOL Technologies, USA."
]

bold: make face/font [name: "Arial Black" size: 480]

logo-shape: [
	transform 0 0.1 0.1 0x0 0x0
	pen none fill-pen black
	shape [
		move 50x0
		'hline  1780 'arc -330 0x600
		'hline -1780 'arc -50x-50
		'vline  -500 'arc 50x-50
		'move 2020x0
		'hline   700 'arc 50x50
		'vline   500 'arc -50x50
		'hline  -700 'arc -330 0x-600
	]
	circle 1950x300 185
	fill-pen white font bold
	text 1 150x0 "R E B"
	text 1 2340x0 "L"
	circle 1950x300 75
]

alert {In the window that follows, change the logo size by resizing the
	window, then click the logo to save it to an image file.}

insert-event-func func [face evt][
	if evt/type = 'resize [
		bx/size: out/size: evt/offset
		bx/size/y: out/size/y: evt/offset/x / 2820 * 600
		n: to-decimal bx/size/x / 2820
		logo-shape/3: n
		logo-shape/4: n
		show out
	]
	evt
]

view/options center-face out: layout [
	origin 0
	bx: box 282x60 white effect [draw logo-shape][
		file: request-file/only/save/file %logo.bmp
		if not file [exit]
		if not find file ".bmp" [append file ".bmp"]
		save/bmp file to-image bx
	]
][resize]